Eine andere Variante, die Freitage in einem Monat auszugeben, ist diese selber zu berechnen.
Hierzu kann man die Funktion „=INDIREKT“ verwenden.

Mit „=INDIREKT“ werden Berechnungen nicht mit absoluten Zell-Koordinaten berechnet, sondern die Angabe der Zell-Koordinaten kann beeinflusst/berechnet werden .
Eine tolle Erklärung gibt es hier:
http://www.giga.de/downloads/microsoft-excel-2013/tipps/excel-indirekt-die-funktion-an-beispielen-erklaert/
Aber ein Schritt nach dem Anderen.
Wichtig ist die Erkennung des Wochentages „Freitag“ …
=Wochentag(Datum(2016;1;7))

… gibt eine 5 aus, da es sich um einen Freitag handelt.
Halt falsch !! Der 7.1.2016 ist ein Donnerstag.

Hier muss die Angabe noch um die Wochentags-Zuordnung ergänzt werden: „2“ besagt, dass die Woche mit Montag beginnt, und nicht – wie im Standard- mit Sonntag.

Richtig wäre also:
=Wochentag(Datum(2016;1;8);2)
Jetzt gibt es für den 8.1.2016 eine 5 aus, da es sich um einen Freitag handelt.

Ergänzt man diese Formel noch um eine Bedingung, bekommt man eine Boolesche Antwort: Ja/Nein, bzw. Wahr/Falsch.
=Wochentag(Datum(2016;1;8);2)=5

Gegenprobe mit dem Datum 7.1.2016
=Wochentag(Datum(2016;1;7);2)=5

Möchte man das Ergebnis noch mathematisch verwerten, so multipliziert man das Ganze einfach mit „1“
=(Wochentag(Datum(2016;1;8);2)=5)*1

Gegenprobe mit dem Datum vom 7.1.2016
=(Wochentag(Datum(2016;1;7);2)=5)*1

Jetzt wird es anspruchsvoller.
Um einen Datumsbereich(!) an „=Wochentag“ zu übergeben, erzeuge ich jetzt eine „Indirekt“-Angabe
INDIREKT(DATUM(2015;9;1)&":"&DATUM(2015;9+1;0))
Da ich an „=Wochentag“ keinen Bereich angeben kann, erzeuge ich diese Werte in virtuellen Zeilen (virtuelle vertikale Matrix)
ZEILE(INDIREKT(DATUM(2015;9;1)&":"&DATUM(2015;9+1;0)))
Dies kann ich jetzt in die Wochentag-Funktion einbinden
WOCHENTAG(ZEILE(INDIREKT(DATUM(2015;9;1)&":"&DATUM(2015;9+1;0)));2)
Da ich auf Freitag abfragen möchte, kommt nun die „zweite“ Bedingung für True/False (siehe oben)
(WOCHENTAG(ZEILE(INDIREKT(DATUM(2015;9;1)&":"&DATUM(2015;9+1;0)));2)=5)
Um diese Mathematisch verarbeiten zu können erfolgt die Multiplizierung mit „1“
(WOCHENTAG(ZEILE(INDIREKT(DATUM(2015;9;1)&":"&DATUM(2015;9+1;0)));2)=5)*1
Jeder Freitag hat jetzt die Ausgabe „1“ und alle anderen Tage eine „0“.
Diese Werte kann ich nun summieren (entspricht : ….0+0+1+0+0+0+0+0+0+1+0+…..)
=SUMME((WOCHENTAG(ZEILE(INDIREKT(DATUM(2015;9;1)&":"&DATUM(2015;9+1;0)));2)=5)*1)
Jetzt noch der letzte Gag:
Wie oben geschrieben, handelt es sich um einen Datumsbereich(!); und möchte man einen Bereich berechnen, muss es eine Matrixformel sein (siehe Blogeintrag Excel: Die Matrixformel)
Also die Formel nicht mit <Return>, sondern mit <STRG>+<SHIFT>+<RETURN> abschließen (Die Formel wird dann in geschweifte Klammern gesetzt:
{=SUMME((WOCHENTAG(ZEILE(INDIREKT(DATUM(2015;9;1)&":"&DATUM(2015;9+1;0)));2)=5)*1)}

Unglaublich, es funktioniert: der Januar 2016 hat 5 Freitag.